Action "tools.npm.upgrade"

const {$status} = await nikita.tools.npm.upgrade({
  global: true
})
console.info(`Packages were upgraded: ${$status}`)

definitions =
  config:
    type: 'object'
    properties:
      'cwd':
        $ref: 'module://@nikitajs/core/lib/actions/execute#/definitions/config/properties/cwd'
      'global':
        type: 'boolean'
        default: false
        description: '''
        Upgrades global packages.
        '''
      'name':
        type: 'array', items: type: 'string'
        description: '''
        Name of the package(s) to upgrade.
        '''
    if: properties: 'global': const: false
    then: required: ['cwd']

handler = ({config, tools: {log}}) ->
  # Get outdated packages
  {packages} = await @tools.npm.outdated
    cwd: config.cwd
    global: config.global
  outdated = for name, info of packages
    continue if info.current is info.wanted
    name
  if config.name
    names = config.name.map (name) -> name.split('@')[0]
    outdated = outdated
    .filter (name) -> names.includes name
  # No package to upgrade
  return unless outdated.length
  # Upgrade outdated packages
  await @execute
    command: [
      'npm'
      'update'
      '--global' if config.global
    ].join ' '
    cwd: config.cwd
  log message: "NPM upgraded packages: #{outdated.join ', '}"

module.exports =
  handler: handler
  metadata:
    definitions: definitions

npm install -g csv-parse@3.0.0
npm update -g
npm ls -g csv-parse # print 4.15.1