Action "ipa.user.del"

const {$status} = await nikita.ipa.user.del({
  uid: "someone",
  connection: {
    url: "https://ipa.domain.com/ipa/session/json",
    principal: "admin@DOMAIN.COM",
    password: "mysecret"
  }
})
console.info(`User was deleted: ${$status}`)

on_action = ({config}) ->
  config.uid ?= config.username
  delete config.username

definitions =
  config:
    type: 'object'
    properties:
      'uid':
        type: 'string'
        description: '''
        Name of the user to delete, same as the `username`.
        '''
      'username':
        type: 'string'
        description: '''
        Name of the user to delete, alias of `uid`.
        '''
      'connection':
        type: 'object'
        $ref: 'module://@nikitajs/network/lib/http#/definitions/config'
        required: ['principal', 'password']
    required: ['connection', 'uid']

handler = ({config}) ->
  config.connection.http_headers['Referer'] ?= config.connection.referer or config.connection.url
  {$status} = await @ipa.user.exists
    $shy: false
    connection: config.connection
    uid: config.uid
  return unless $status
  await @network.http config.connection,
    negotiate: true
    method: 'POST'
    data:
      method: "user_del/1"
      params: [[config.uid], {}]
      id: 0

module.exports =
  handler: handler
  hooks:
    on_action: on_action
  metadata:
    definitions: definitions